bk commit into 5.1 tree (serg:1.2417)

[Sergei Golubchik]

Below is the list of changes that have just been committed into a local
5.1 repository of serg. When serg does a push these changes will
be propagated to the main repository and, within 24 hours after the
push, to the public repository.
For information on how to access the public repository
see http://dev.mysql.com/doc/mysql/en/installing-source-tree.html

ChangeSet@stripped, 2007-02-02 20:40:19+01:00, serg@stripped +3 -0
  /usr/share/aclocal/mysql.m4

  server-tools/CMakeLists.txt@stripped, 2007-02-02 12:04:32+01:00, serg@stripped +0 -0
    Change mode to -rw-rw-r--

  support-files/Makefile.am@stripped, 2007-02-02 20:40:16+01:00, serg@stripped +3 -0
    /usr/share/aclocal/mysql.m4

  support-files/mysql.m4@stripped, 2007-02-02 20:40:16+01:00, serg@stripped +84 -0
    /usr/share/aclocal/mysql.m4

  support-files/mysql.m4@stripped, 2007-02-02 20:40:16+01:00, serg@stripped +0 -0

# This is a BitKeeper patch.  What follows are the unified diffs for the
# set of deltas contained in the patch.  The rest of the patch, the part
# that BitKeeper cares about, is below these diffs.
# User:	serg
# Host:	janus.mylan
# Root:	/usr/home/serg/Abk/mysql-5.1

--- 1.33/support-files/Makefile.am	2007-02-02 20:40:25 +01:00
+++ 1.34/support-files/Makefile.am	2007-02-02 20:40:25 +01:00
@@ -43,6 +43,9 @@
 
 pkgdata_SCRIPTS =	mysql.server
 
+aclocaldir =		$(datadir)/aclocal
+aclocal_DATA =		mysql.m4
+
 noinst_DATA = mysql-@VERSION@.spec \
 			MySQL-shared-compat.spec
 
--- New file ---
+++ support-files/mysql.m4	07/02/02 20:40:16
# Copyright (C) 2007 MySQL AB
# 
# This program is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by the Free
# Software Foundation; version 2 of the License.
#
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
# or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
# for more details.
#
# You should have received a copy of the GNU General Public License along
# with this program; if not, write to the Free Software Foundation, Inc., 59
# Temple Place, Suite 330, Boston, MA  02111-1307  USA

AC_DEFUN([_MYSQL_CONFIG],[
  AC_ARG_WITH([mysql-config],
  AS_HELP_STRING([--with-mysql-config], [A path to mysql_config script]),
                 [mysql_config="$withval"], [mysql_config=mysql_config])
])

dnl
dnl Usage:
dnl
dnl  MYSQL_CLIENT([version], [client|thread-safe|embedded])
dnl
dnl Two optional arguments:
dnl   first: The minimal version of the MySQL to use
dnl           if not specified, any version will be accepted
dnl   second: force the specified library flavor to be selected,
dnl           if not specified, a user will be able to choose
dnl           between client (non-thread-safe) and embedded
dnl

AC_DEFUN([MYSQL_CLIENT],[
  AC_REQUIRE([_MYSQL_CONFIG])
  AC_MSG_CHECKING([for MySQL])
  ifelse([$2], [client],
               [mysql_libs=--libs mysql_cflags=--cflags],
         [$2], [thread-safe],
               [mysql_libs=--libs_r mysql_cflags=--cflags],
         [$2], [embedded],
               [mysql_libs=--libmysqld-libs mysql_cflags=--cflags],
         [$2], [], [
    AC_ARG_WITH([mysql-library],
    AS_HELP_STRING([--with-mysql-library], ['client' or 'embedded']),
                   [mysql_lib="$withval"], [mysql_lib=client])
[                   
    case "$mysql_lib" in
      client) mysql_libs=--libs mysql_cflags=--cflags ;;
      embedded) mysql_libs=--libmysqld-libs mysql_cflags=--cflags ;;
      *) ]AC_MSG_ERROR([Bad value for --with-mysql-library])[
    esac
]
                   ],
          [AC_FATAL([Bad argument to MYSQL_CLIENT])])
[
    mysql_version=`$mysql_config --version`
    if test -z "$mysql_version" ; then
      ]AC_MSG_ERROR([Cannot execute $mysql_config])[
    fi
]
    ifelse([$1], [], [], [
    mysql_ver=`echo .${mysql_version}.|dnl
    sed 's/\.\([[0-9]]\)\./.0\1./g;dnl
         s/\.\([[0-9]]\)\./.0\1./g;dnl
         s/-.*//; s/\.//g'`
    if test "$mysql_ver" -lt]dnl
    patsubst(patsubst(patsubst(.[$1]., [\.\([0-9]\)\.], [.0\1.]), [\.\([0-9]\)\.], [.0\1.]), [\.], [])[ ; then
      AC_MSG_ERROR([MySQL version $mysql_version is too low, minimum of $1 is required])
    fi
    ])

    MYSQL_CLIENT_CFLAGS=`$mysql_config $mysql_cflags`
    MYSQL_CLIENT_LIBS=`$mysql_config $mysql_libs`
    AC_SUBST(MYSQL_CLIENT_CFLAGS)
    AC_SUBST(MYSQL_CLIENT_LIBS)

    # should we try to build a test program ?
    # No, not yet

    AC_MSG_RESULT([$mysql_version])
])